FGA ライブラリを使用した例

この例では、FGA ライブラリを使用しています。
fnFGA プレフィックスの関数が FGA ライブラリの関数です。 これらの関数は fvalgcli.fga 配下に集約されています。

FGA インストーラは、WIL 本体のインストーラとは分離していますので、別途インストールする必要があります。
また、FGA ライブラリを使用するには "fvalgcli for FGA" を参照設定に追加する必要があります。

---

コード例:

Partial Public Class TestClass
   ''' <summary>
   ''' FGA ライブラリを使用した例.
   ''' </summary>
   Public Sub Test3()
       Dim status As f_err
       Dim src As FVIL.Data.CFviImage = Nothing
       Dim dst As FVIL.Data.CFviImage = Nothing
       Dim hfga_src As FHANDLE = IntPtr.Zero
       Dim hfga_dst1 As FHANDLE = IntPtr.Zero
       Dim hfga_dst2 As FHANDLE = IntPtr.Zero
       Dim type As Int32
       Dim channels As Int32
       Dim width As Int32
       Dim height As Int32

       If fga.fnFGA_is_setuped() = False Then
           Return
       End If

       Try
           '' ==================================================
           '' 入力.
           src = New FVIL.Data.CFviImage("Data/key_UC8_M.png")

           type = api.fnFIE_img_get_type(src.GetFIE())
           channels = api.fnFIE_img_get_channels(src.GetFIE())
           width = api.fnFIE_img_get_width(src.GetFIE())
           height = api.fnFIE_img_get_height(src.GetFIE())

           '' 生成.
           hfga_src = fga.fnFGA_img_root_alloc(type, channels, width, height)

           '' コピー.(FIE → FGA)
           fga.fnFGA_img_copy(src.GetFIE(), hfga_src)

           '' ==================================================
           '' 処理.
           type = fga.fnFGA_img_get_type(hfga_src)
           channels = fga.fnFGA_img_get_channels(hfga_src)
           width = fga.fnFGA_img_get_width(hfga_src)
           height = fga.fnFGA_img_get_height(hfga_src)

           '' 生成.
           hfga_dst1 = fga.fnFGA_img_root_alloc(type, channels, width, height)
           hfga_dst2 = fga.fnFGA_img_root_alloc(type, channels, width, height)

           '' 平均化.
           status = fga.fnFGA_average(hfga_src, hfga_dst1, f_border_mode.F_BORDER_CONTINUOUS, 0.0)
           If status <> f_err.F_ERR_NONE Then
               Console.WriteLine("fnFGA_average failed.({0})", status)
               Throw New FvException(status)
           End If

           '' ソーベル.
           status = fga.fnFGA_sobel(hfga_dst1, hfga_dst2, f_sobel_mode.F_SOBEL_XY_MODE, f_border_mode.F_BORDER_CONTINUOUS, 0.0)
           If status <> f_err.F_ERR_NONE Then
               Console.WriteLine("fnFGA_sobel failed.({0})", status)
               Throw New FvException(status)
           End If

           '' ==================================================
           '' 出力.
           type = fga.fnFGA_img_get_type(hfga_dst2)
           channels = fga.fnFGA_img_get_channels(hfga_dst2)
           width = fga.fnFGA_img_get_width(hfga_dst2)
           height = fga.fnFGA_img_get_height(hfga_dst2)

           '' 生成.
           Dim hfie_dst As FHANDLE = api.fnFIE_img_root_alloc(type, channels, width, height)

           '' コピー.(FGA → FIE)
           fga.fnFGA_img_copy(hfga_dst2, hfie_dst)

           '' ファイル保存.
           dst = New FVIL.Data.CFviImage(hfie_dst, False)
           dst.Save("Result/Result3.png")
       Finally
           '' 解放.
           If src IsNot Nothing Then src.Dispose()
           If dst IsNot Nothing Then dst.Dispose()
           hfga_src.Dispose()
           hfga_dst1.Dispose()
           hfga_dst2.Dispose()
       End Try
   End Sub

   ''' <summary>
   ''' エントリポイントの例.
   ''' </summary>
   Public Sub main()
       '' 初期化.
       Dim status As Int32 = fga.fnFGA_setup()

       If status = f_err.F_ERR_NONE Then
           Test3()
       End If

       '' 解放.
       fga.fnFGA_teardown()
   End Sub

End Class

※注)
FGA ライブラリの初期化は暗黙的には行われませんので、 上記のようにアプリケーションのエントリポイント等で初期化関数を呼び出す必要があります。